Kết quả 1 đến 8 của 8

Chủ đề: Xin giúp tách chuỗi giữa 2 dấu phẩy cuối cùng

  1. #1
    Ngày tham gia
    Aug 2015
    Bài viết
    0

    Xin giúp tách chuỗi giữa 2 dấu phẩy cuối cùng

    Xin các tiền bối giúp dùm ca này quá khó, đã tìm trong diễn đàn mà ko thấy,

    Nội dung: dùng hàm excel tách lấy chuỗi nằm giữa 2 dấu phẩy cuối cùng trong ô.

    ví dụ: chuỗi nguồn: 13776,123,45689,999,000,375111,222222,35
    nội dung cần lấy: 222222

    Em gởi kèm file để các tiền bối nhìn rõ hơn,

    Xin cám ơn rất nhiều!!!

  2. #2
    wapa Guest
    Công thức này nhe bạn:

    Mã:
    C2=TRIM(RIGHT(SUBSTITUTE(SUBSTITUTE(B2,","&TRIM(RIGHT(SUBSTITUTE(B2,",",REPT(" ",255)),254)),""),",",REPT(" ",255)),254))
    Rồi fill xuống!!

  3. #3
    thinhvuonghouse Guest
    Trích dẫn Gửi bởi yangmingchao
    Xin các tiền bối giúp dùm ca này quá khó, đã tìm trong diễn đàn mà ko thấy,

    Nội dung: dùng hàm excel tách lấy chuỗi nằm giữa 2 dấu phẩy cuối cùng trong ô.

    ví dụ: chuỗi nguồn: 13776,123,45689,999,000,375111,222222,35
    nội dung cần lấy: 222222

    Em gởi kèm file để các tiền bối nhìn rõ hơn,

    Xin cám ơn rất nhiều!!!
    Bạn thử nhập công thức này vào ô C2:

    Mã nguồn PHP:
    =TRIM(LEFT(RIGHT(SUBSTITUTE(B2;",";REPT(" ";250));500);250))  
    Nếu bị lỗi thì thay dấu ; thành dấu ,

  4. #4
    giangvan89 Guest
    Trích dẫn Gửi bởi Ba Tê
    Bạn thử nhập công thức này vào ô C2:

    <div class="bbcode_container">
    <div class="bbcode_description">PHP Code:
    </div>
    </div>
    </div>
    Công thức của thầy hay ghê!!![IMG]images/smilies/a44.gif[/IMG]

  5. #5
    baobinh Guest
    Một cách viết khác tại D2:

    Mã:
    =TRIM(MID(SUBSTITUTE(B2,",",REPT(" ",100)),(LEN(B2)-LEN(SUBSTITUTE(B2,",",""))-1)*100,100))

  6. #6
    taidienlanh Guest
    Trích dẫn Gửi bởi Ba Tê
    Muốn hiểu 1 công thức kết hợp nhiều hàm, bạn phải "mò" ngược từng hàm từ sau ra trước, từ trong ra ngoài.
    =TRIM(LEFT(RIGHT(SUBSTITUTE(B2;",";REPT(" ";250));500);250))
    1/ REPT(" ";250)
    2/ SUBSTITUTE(B2;",";REPT(" ";250))
    3/ RIGHT(SUBSTITUTE(B2;",";REPT(" ";250));500)
    4/ LEFT(RIGHT(SUBSTITUTE(B2;",";REPT(" ";250));500);250)
    5/ Trim(...)
    Nghiên cứu sử dụng ở đây, ngẫm ra thì sẽ "khoái" hơn.
    http://www.giaiphapexcel.com/forum/s...4708#post54708
    Xinc ám ơn thầy rất nhiều!

  7. #7
    nguyenngoc20 Guest
    Xin cám ơn thầy rất nhiều! đã giải quyết được dựa trên công thức của thầy.
    Nếu tiện, thầy có thể giúp giải thích các phần của công thức được không ạ? vì em muốn hiểu được và ứng dụng về sau.

    Xin chân thành cám ơn!

  8. #8
    meomon1209 Guest
    Trích dẫn Gửi bởi yangmingchao
    Xin cám ơn thầy rất nhiều! đã giải quyết được dựa trên công thức của thầy.
    Nếu tiện, thầy có thể giúp giải thích các phần của công thức được không ạ? vì em muốn hiểu được và ứng dụng về sau.

    Xin chân thành cám ơn!
    Muốn hiểu 1 công thức kết hợp nhiều hàm, bạn phải "mò" ngược từng hàm từ sau ra trước, từ trong ra ngoài.
    =TRIM(LEFT(RIGHT(SUBSTITUTE(B2;",";REPT(" ";250));500);250))
    1/ REPT(" ";250)
    2/ SUBSTITUTE(B2;",";REPT(" ";250))
    3/ RIGHT(SUBSTITUTE(B2;",";REPT(" ";250));500)
    4/ LEFT(RIGHT(SUBSTITUTE(B2;",";REPT(" ";250));500);250)
    5/ Trim(...)
    Nghiên cứu sử dụng ở đây, ngẫm ra thì sẽ "khoái" hơn.
    http://www.giaiphapexcel.com/forum/s...4708#post54708

Quyền viết bài

  • Bạn Không thể gửi Chủ đề mới
  • Bạn Không thể Gửi trả lời
  • Bạn Không thể Gửi file đính kèm
  • Bạn Không thể Sửa bài viết của mình
  •