Trang 1 của 2 12 CuốiCuối
Kết quả 1 đến 10 của 13

Chủ đề: Công thức tìm vị trí ô đầu tiên, ô cuối cùng theo điều kiện

  1. #1
    giangvan89 Guest

    Công thức tìm vị trí ô đầu tiên, ô cuối cùng theo điều kiện

    A .Tìm vị trí ô đầu tiên, ô cuối cùng trong cùng một cột thỏa điều kiện

    1. Dòng đầu tiên khác rỗng :

    Mã nguồn PHP:
    =SUMPRODUCT(MATCH(TRUE,A$1:A$65535<>"",0))  
    2. Dòng đầu tiên khác rỗng với dữ liệu chuỗi :

    Mã nguồn PHP:
    =MATCH("*",A:A,0)  
    3. Dòng đầu tiên khác rỗng với dữ liệu số :

    Mã nguồn PHP:
    {=MIN(IF(ISNUMBER(A1:A65535),ROW(A1:A65535)))}  
    4. Dòng cuối cùng khác rỗng :

    Mã nguồn PHP:
    =SUMPRODUCT(MAX(((A$1:A$65535<>"")*ROW(A$1:A$65535)))) =MAX(MATCH(9.99999999999999E+307,A:A),MATCH(REPT("z",255),A:A))  
    5. Dòng cuối cùng khác rỗng với dữ liệu số :

    Mã nguồn PHP:
    =MATCH(9.99999999999999E+307,A:A)  
    6. Dòng cuối cùng khác rỗng với dữ liệu chuỗi :

    Mã nguồn PHP:
    =MATCH(REPT("z",255),A:A)  
    B .Tìm giá trị ô đầu tiên, ô cuối cùng trong cùng một cột thỏa điều kiện

    1. Giá trị ô đầu tiên khác rỗng :

    Mã nguồn PHP:
    =INDEX(A:A,SUMPRODUCT(MATCH(TRUE,A$1:A$65535<>"",0)))  
    2. Giá trị ô đầu tiên khác rỗng với dữ liệu chuỗi:

    Mã nguồn PHP:
    =INDEX(A:A,MATCH("*",A:A,0))  
    3. Giá trị ô đầu tiên khác rỗng với dữ liệu số:

    Mã nguồn PHP:
    {=INDEX(A:A,MIN(IF(ISNUMBER(A1:A65535),ROW(A1:A65535))))}  
    4. Giá trị ô cuối cùng khác rỗng :

    Mã nguồn PHP:
    =INDEX(A:A,MAX(MATCH(9.99999999999999E+307,A:A),MATCH(REPT("z",255),A:A)))  
    5. Giá trị ô cuối cùng khác rỗng với dữ liệu số :

    Mã nguồn PHP:
    =LOOKUP(9.99999999999999E+307,A:A)  
    6. Giá trị ô cuối cùng khác rỗng với dữ liệu chuỗi :

    Mã nguồn PHP:
    =LOOKUP(REPT("z",255),A:A)  
    C. Tìm vị trí của ô đầu tiên, ô cuối cùng có chứa dữ liệu tìm kiếm :

    Row of Lastcell with lookup_value :

    Mã nguồn PHP:
    {=MAX(((A1:A100=lookup_value)*ROW(A1:A100)))} press Ctrl+Shif+Enter  
    Row of Firstcell with lookup_value :

    Mã nguồn PHP:
    {=SMALL(((A1:A100=lookup_value)*ROW(A1:A100)),SUMPRODUCT(--NOT((A1:A100=lookup_value)))+1)} press Ctrl+Shif+Enter  
    Tương tự cho dòng

  2. #2
    lehue2603 Guest
    Nhập thêm vài công thức giống như vậy nữa. Tìm giá trị số ở cột cuối cùng trong vùng A3:F3
    Trích dẫn Gửi bởi hoangdanh282vn
    lookup(1E+307,A3:F3) Đây là công thức đặc biệt, nó sẽ tìm giá trị số ở cột cuối cùng trong vùng A3:F3 Hay tổng quát là Lookup(1E+307,1:1) Tìm giá trị số ở cột cuối cùng trong hàng thứ nhất.Số 1E+307 có thể là 2E+307... Anh xem thêm bài viết của em ở đây, nói riêng về tìm dữ liệu trong trong 1 cột. Trong 1 hàng thì đảo vùng lại, VD A:A thành 1:1 http://www.giaiphapexcel.com/forum/showthread.php?t=12438
    Nguồn: http://www.giaiphapexcel.com/forum/s...t=3369&page=77

  3. #3
    vivaclinic Guest
    Còn thiếu dòng đầu tiên với số, giá trị số đầu tiên. Danh làm nốt đi cho trọn.

  4. #4
    minhtien123 Guest
    Công thức này:


    =LOOKUP(2,1/(1-ISBLANK(A1:A65535)),A1:A65535)
    Dùng để tìm giá trị cuối cùng khác rổng... Nó đúng với mọi kiểu dử liệu

  5. #5
    jindovn Guest
    Các bạn giúp hộ 2 công thức:
    1. Dòng đầu tiên khác rỗng với dữ liệu số
    2. Giá trị ô đầu tiên khác rỗng với dữ liệu số
    Xin cám ơn

  6. #6
    QuynhTrang Guest
    Trích dẫn Gửi bởi ngo15
    Các bạn giúp hộ 2 công thức:
    1. Dòng đầu tiên khác rỗng với dữ liệu số
    2. Giá trị ô đầu tiên khác rỗng với dữ liệu số
    Xin cám ơn
    Bạn chịu khó đọc các bài bên trên sẽ thấy! Cụ thể là bạn đọc tại bài #1 của topic này sẽ rõ.

  7. #7
    Ngày tham gia
    Aug 2015
    Bài viết
    4
    Tôi đã đọc kỹ bài #1 chỉ có:
    1. Dòng đầu tiên khác rỗng :
    2. Dòng đầu tiên khác rỗng với dữ liệu chuỗi :
    chứ không có Dòng đầu tiên khác rỗng với dữ liệu số
    Khi dòng đầu tiên không phải số thì áp dụng 2 công thức trên không được.
    Xin cám ơn

  8. #8
    Ngày tham gia
    Aug 2015
    Bài viết
    0
    Trích dẫn Gửi bởi ngo15
    Tôi đã đọc kỹ bài #1 chỉ có:
    1. Dòng đầu tiên khác rỗng :
    2. Dòng đầu tiên khác rỗng với dữ liệu chuỗi :
    chứ không có Dòng đầu tiên khác rỗng với dữ liệu số
    Khi dòng đầu tiên không phải số thì áp dụng 2 công thức trên không được.
    Xin cám ơn
    Nếu người ta nói Dòng đầu tiên khác rỗng và không nói gì thêm có nghĩa là kiểu dử liệu nào cũng OK
    Bạn làm không được thì đưa ví dụ lên xem
    Ghi chú: Công thức 1 chỉ là tìm vị trí dòng chứa cell đầu tiên (không phải lấy giá trị cell)

  9. #9
    Ngày tham gia
    Aug 2015
    Bài viết
    1
    Trích dẫn Gửi bởi ngo15
    Tôi đã đọc kỹ bài #1 chỉ có:
    1. Dòng đầu tiên khác rỗng :
    2. Dòng đầu tiên khác rỗng với dữ liệu chuỗi :
    chứ không có Dòng đầu tiên khác rỗng với dữ liệu số
    Khi dòng đầu tiên không phải số thì áp dụng 2 công thức trên không được.
    Xin cám ơn
    Bạn xem công thức trong file nhé.

  10. #10
    phongphongphong1992 Guest
    Salam dùng 1 công thức khác để tìm cell đầu tiên...
    Còn file này tôi dùng đúng công thức 1 (mà bạn nói làm không được) đây:

Trang 1 của 2 12 CuốiCuối

Quyền viết bài

  • Bạn Không thể gửi Chủ đề mới
  • Bạn Không thể Gửi trả lời
  • Bạn Không thể Gửi file đính kèm
  • Bạn Không thể Sửa bài viết của mình
  •